// Copyright The Perses Authors
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

package common

#baseAction: {
	name:            string
	icon?:           string
	confirmMessage?: string
	enabled:        bool | *true
	bodyTemplate?: string
	batchMode:     "batch" | *"individual"
}
#eventAction: {
	#baseAction
	type:      "event"
	eventName: string
}
#webhookAction: {
	#baseAction
	type:   "webhook"
	url:    string
	method: "GET" | *"POST" | "PUT" | "PATCH" | "DELETE"
	contentType: *"none" | "json" | "text"
	headers?: [string]: string
}

#itemAction: #eventAction | #webhookAction

#actions: {
	enabled: bool | *true
	actionsList: [...#itemAction]
	displayInHeader?: bool
	displayWithItem?: bool
}